Re:simulationsprogramm
Hi,
es gibt spice3f5.
Ich hab' zwar kein Windows, aber es sollte da was geben...
Zum Einstieg kannst Du folgendes Programm verwenden (copy & paste)
--- nach dieser Zeile anfangen
* Test-Circuit to show some of the 12AX7 behaviour
*.PRINT AC VM(3)
***************************** ANALYSIS *****************************
.OP
*.TRAN 1u 4m 0 2u
.AC OCT 8 20 20k
*************************** SOURCES**** ***************************
VB 100 0 DC 300
VIN 10 0 AC 1 DC 0 SIN(0 1m 1k)
************************** PREAMP CIRCUIT **************************
*
*** V1B
R1 1 0 1Meg
R2 1 2 68k
R3 100 3 100k
R4 4 0 10k
#C1 4 0 1u
C2 3 5 22n
XV1B 3 2 4 12AX7
Rhelp1 5 0 1T
*** 12AX7 MODELL ***********************************************
.SUBCKT 12AX7 A G K
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1.5 )* 0.000016
BGG GG 0 V=V(G)-V(K)--0.53056
BRP1 RP1 0 V=URAMP(-V(GG)* 0.076498 )
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.18
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)*-0.013621 )))
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 87.302 )
BEP EP 0 V=(V(EM)^ 1.5 )*V(RP)* 0.00000111
BEL1 EL1 0 V=URAMP(V(EP))
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD LD 0 V=URAMP(V(EP)-V(LI))
BAK A K I=V(EL)
BGF GF 0 V=(URAMP(V(G)-V(K)--0.2 )^1.5)* 0.00001
BG G K I=V(GF)+V(LD)
CAK A K 0.0000000000007
CGK G K 0.0000000000024
CGA G A 0.0000000000017
.ENDS 12AX7
.END
--- vor dieser Zeile aufhören
Die weitere Bedienung würde jetzt zu weit führen...
Gruß
Andy